使用Jmail4.0发送HTML邮件_

使用Jmail4.0发送HTML邮件

2005-11-16 7:31:34　　作者：模板天下收集整理　　来源：未知　网友评论 0 条　论坛

　　这个功能基于Jmail 4.0 实现,要求你的服务器已经安装Jmail并开放相关功能.

下面给出一个ASP实例,希望对大家有帮助.

名称:在线职位申请系统(表单-邮件系统) sendmail.asp

假设:链接指向


http://www.dovia.net/apply.asp?classid=42&topic=新闻助理

apply.asp 包含一个常见的申请表单集(要求填写姓名/性别/生日/学历等)
form action 指向sendmail.asp

sendmail.asp 代码内容 (注意阅读注释,将必要部分改为你的实际情况)


<% 
If (cStr(Request("classid")) <> "") Then
Dim theSubject
theSubject=Request.QueryString("topic") '从传递过来的url参数获得邮件主题名
'定义所需变量
Dim realname,birthday,sex,marriage,social,stature,prc,idcard,tele,email,address,salary,learn,exper,target
realname=Request.Form("realname")'从表单获取发件人姓名
sex=Request.Form("sex")'从表单获取发件人性别
marriage=Request.Form("marriage")'从表单获取发件人婚姻状况
birthday=Request.Form("birthday")'从表单获取发件人性别
social=Request.Form("social")'从表单获取发件人政治面貌
stature=Request.Form("stature")'从表单获取发件人身高
prc=Request.Form("prc")'从表单获取发件人户口所在地
idcard=Request.Form("idcard")'从表单获取发件人身份证号码
tele=Request.Form("tele")'从表单获取发件人电话
email=Request.Form("email")'从表单获取发件人email
address=Request.Form("address")'从表单获取发件人住址
salary=Request.Form("salary")'从表单获取发件人期待薪酬
learn=Request.Form("learn")'从表单获取发件人学历
exper=Request.Form("exper")'从表单获取发件人工作经历
target=Request.Form("target")'从表单获取发件人个人目标

Dim JMail
Set JMail = Server.CreateObject("JMail.Message") 

JMail.Charset = "gb2312" ' 邮件字符集，默认为"US-ASCII" 
' JMail.ISOEncodeHeaders = False ' 是否进行ISO编码，默认为True 
JMail.ContentType = "text/html" '邮件头设置， 默认为 "text/plain" ,发送HTML信息,改为 "text/html"

' 发送者信息（可用变量方式赋值） 
JMail.From = "三叶草工作室" ' 发送者地址 
JMail.FromName = "Studio S.Y.C" ' 发送者姓名 
JMail.Subject = "职位申请函" ' 邮件主题 

' 身份验证 
JMail.MailServerUserName = "yourMailServerUserName" ' 身份验证的用户名 
JMail.MailServerPassword = "yourMailServerPassword" ' 身份验证的密码 

' 设置优先级，范围从1到5，越大的优先级越高，3为普通 
JMail.Priority = 3 

JMail.AddHeader "Originating-IP", Request.ServerVariables("REMOTE_ADDR") 

' 加入一个收件人【变量email：收件人地址】可以同一语句重复加入多个 
JMail.AddRecipient "youremail@mail.com"

' 加入附件【变量filename：附件文件的绝对地址，确保用户IUSR_????有访问的权限】
' 变量filename值可以来自一个上传表单域,本例省略
' 【参数设置是(True)否(False)为Inline方式】
'attachfile = JMail.AddAttachment (filename, True)

' 邮件主体（HTML(注意信件内链接附件的方式)） 
JMail.Body = "<html><head><title>应聘资料-申请职位"&theSubject&_
"</title><meta http-equiv=""Content-Type"" content=""text/html; charset=gb2312"">"&_
"<style type=""text/css""><!--.style1 {color: #CC0000;font-weight: bold;}-->"&_
"</style></head><body><table width=""100%"" border=""0"" cellpadding=""0"""&_
" cellspacing=""1"" bgcolor=""#990000""><tr><td><table width=""100%"""&_
" border=""0"" align=""center"" cellpadding=""6"" cellspacing=""0"" "&_
"bgcolor=""#FFFFFF""><tr><td height=""25"" bgcolor=""#CCCCCC"">"&_
"<span class=""style1"">申请职位: "&theSubject&"</span></td></tr>"&_
"<tr><td height=""25"" bgcolor=""#F5F5F3""><span class=""style1"">申请人资料</span></td></tr>"&_
"<tr><td>姓名:"&realname&"</td></tr><tr><td>性别:"&sex&"</td></tr>"&_
"<tr><td>出生年月:"&birthday&"</td></tr><tr><td> 婚姻状况:"&marriage&"</td></tr>"&_
"<tr><td>政治面貌:"&social&"</td></tr><tr><td>身高:"&stature&"cm</td></tr>"&_
"<tr><td>户口所在地:"&prc&"</td></tr><tr><td>身份证号码:"&idcard&"</td></tr>"&_
"<tr><td>联系电话:"&tele&"</td></tr><tr><td>联系Email:"&email&"</td></tr>"&_
"<tr><td>联系地址:"&address&"</td></tr><tr><td>期望月薪:"&salary&"　</td></tr>"&_
"<tr><td>学历:"&learn&"</td></tr><tr><td>工作经历:"&exper&"</td></tr>"&_
"<tr><td>个人目标:"&target&"</td></tr>"&_
"<tr><td><br>此邮件来自三叶草申请系统,三叶草企业邮局版权所有.<br></td></tr></table></td></tr>"&_
"</table></body></html>" 

' 发送【调用格式：SMTPServerAddress)】 
JMail.Send("mail.youremail.com") 

' 关闭并清除对象 
JMail.Close() 
Set JMail = Nothing 
Response.Redirect("sendok.asp")'发送完成后转向成功页面
End If

%>

邮件发送后用OE或者WEB形式收取就能看见效果了(若用OE收取请打开HTML邮件显示功能)

共分1页 [1]

>> 相关文章